OneDrive ist unter Windows 10 standardmäßig installiert. Wer OneDrive nicht benötigt, kann diese mit einem kleinen Umweg komplett entfernen. Allerdings sollte man bei diesem Vorhaben sehr vorsichtig sein und genau wissen was man tut, da OneDrive sehr tief in Windows 10 integriert ist. In vielen Fällen kann dies zu erheblichen Problemen führen. Aus diesem Grund würde ich hier eher zu einer Deaktivierung von OneDrive raten.

Nichtsdestotrotz möchte ich euch die Möglichkeit der kompletten Entfernung von OneDrive nicht vorenthalten. Dazu müsst ihr lediglich den nachfolgenden Code kopieren, eine Batch-Datei erstellen und anschließend ausführen. Wer den Code nicht selbst in eine Batch-Datei packen möchte, kann sich weiter unten auch das fertige Skript downloaden.

@echo off
cls

set x86="%SYSTEMROOT%\System32\OneDriveSetup.exe"
set x64="%SYSTEMROOT%\SysWOW64\OneDriveSetup.exe"

echo OneDrive Prozess beenden
echo.
taskkill /f /im OneDrive.exe > NUL 2>&1
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive deinstallieren
echo.
if exist %x64% (
%x64% /uninstall
) else (
%x86% /uninstall
)
ping 127.0.0.1 -n 5 > NUL 2>&1

echo OneDrive Überreste entfernen
echo.
rd "%USERPROFILE%\OneDrive" /Q /S > NUL 2>&1
rd "C:\OneDriveTemp" /Q /S > NUL 2>&1
rd "%LOCALAPPDATA%\Microsoft\OneDrive" /Q /S > NUL 2>&1
rd "%PROGRAMDATA%\Microsoft OneDrive" /Q /S > NUL 2>&1 

echo OneDrive im Datei Explorer entfernen
echo.
REG DELETE "HKEY_CLASSES_ROOT\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CLASSES_ROOT\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1
REG DELETE "HKEY_CURRENT_USER\Software\Classes\Wow6432Node\CLSID\{018D5C66-4533-4307-9B53-224DE2ED1FE6}\ShellFolder" /f > NUL 2>&1

pause

Download Skript zur Entfernung von OneDrive unter Windows 10

Windows 10 wird standardmäßig mit OneDrive ausgeliefert. Wer kein Online-Konto oder OneDrive benutzt, kann die Software unter Windows 10 ohne Probleme deaktivieren.

Möglichkeit 1: Editor für lokale Gruppenrichtlinien

Der einfachste Weg zur Deaktivierung von OneDrive führt über die lokalen Gruppenrichtlinien. Diese Variante ist allerdings nur unter Windows 10 Pro und Enterprise möglich. Nutzer der Home-Edition müssen zu Möglichkeit 2 greifen.

1. Den Ausführen-Dialog (Windows-Taste + R) öffnen und „gpedit.msc“ eingeben.
2. Unter „Computerkonfiguration“ zu „Administrative Vorlagen“, „Windows-Komponenten“ und „OneDrive“ wechseln.
3. Im rechten Fensterbereich auf „Verwendung von OneDrive für die Datenspeicherung verhindern“ doppelklicken.
4. In dem neu geöffneten Fenster „Aktiviert“ auswählen und die Änderungen bestätigen.
5. Nach einem Neustart ist OneDrive deaktiviert.

Möglichkeit 2: Registrierungs-Editor

Nutzer von Windows 10 Home können die erste Möglichkeit nicht verwenden, da dort keine Gruppenrichtlinien existieren. Hier führt der Weg über die Registry.

1. Den Ausführen-Dialog (Windows-Taste + R) öffnen und „regedit“ eingeben, damit der Registrierungs-Editor geöffnet wird.
2. Anschließend zu folgendem Pfad navigieren:

3. HKEY_LOCAL_MACHINE\SOFTWARE\Policies\Microsoft\Windows\Onedrive

4. Darunter muss ein neuer „DWORD-Wert (32-Bit)“ mit dem Namen „DisableFileSyncNGSC“ erstellt werden.
5. Dieser erhält den Wert auf „1„. Außerdem wird der Wert „DisableFileSync“ auf „1„ gesetzt.
6. Anschließend müssen Schritt vier und fünf unter folgendem Pfad wiederholt werden:

   HKEY_LOCAL_MACHINE\SOFTWARE\Wow6432Node\Policies\Microsoft\Windows\Onedrive

7. Nach einem Neustart sollten die Änderungen wirksam sein.

Zur einfacheren Umsetzung biete ich eine Registrierungsdatei an, die alle Änderungen in der Registry automatisch durchführt.